100 '------------------------------------------------
110 '   N気筒星形エンジン　アニメーションプログラム
130 '------------------------------------------------
140 SCREEN 3 : CLS 3
150 X0=320 : Y0=200             '原点(クランクケース中心)座標
160 R=15 : L=50 : K=90          'R;偏心量　L;コンロッド長 K;補助線長さ
170 N=9 : Z=2 : W=1             'N;気筒数　Z;拡大率
180 H=10 : D=16 : C=2           'H;ピストン高さ  D;ピストン径 C;シリンダとのスキマ
190 CL=2*R+C+H                  'CL;シリンダ長
200 CD=(D+C)/2 :CT=L+R+C/2+H/2  'CD;シリンダ径　CT;クランクケース中心からシリンダ頂点の距離
210 PI=3.14159
220 FOR S=0 TO 2*PI/N STEP 0.01 '各気筒が隣の位置まで回転する角度
225 W=W+1
230 AP=(W+1) MOD 2 : DP=(W MOD 2)*17 : IF DP=0 THEN DP=1   '画面切り替え
240 SCREEN ,,AP,DP
250 CLS 2
260 FOR T=S-PI/2 TO S+1.5*PI-0.001 STEP 2*PI/N        'N気筒分描画
270 HANTEI=4*R*R*TAN(T)*TAN(T)-4*(1+TAN(T)*TAN(T))*(R*R-L*L)
280 IF PI/2<T THEN 290 ELSE 300
290 X=(2*R*TAN(T)-HANTEI^.5#)/(2*(1+TAN(T)*TAN(T))):GOTO 310
300 X=(2*R*TAN(T)+HANTEI^.5#)/(2*(1+TAN(T)*TAN(T)))
310 Y=TAN(T)*X
320 'LINE (X0,Y0)-(X0,Y0-R*Z),7
330 'CIRCLE (X0,Y0-R*Z),L*Z,6
340 CIRCLE (X0+X*Z,Y0-Y*Z),4,5                         'ピストンピン
350 LINE (X0,Y0-R*Z)-(X0+X*Z,Y0-Y*Z),7                 '偏心量のとこの線
360 'LINE (X0,Y0)-(X0+K*COS(T)*Z,Y0-K*SIN(T)*Z),4      '補助線
370 HCOS=H/2*COS(T) : DSIN=D/2*SIN(T) : HSIN=H/2*SIN(T) : DCOS=D/2*COS(T) 'ピストン
380 P1X=X+HCOS+DSIN:P1Y=Y+HSIN-DCOS
390 P2X=X+HCOS-DSIN:P2Y=Y+HSIN+DCOS
400 P3X=X-HCOS-DSIN:P3Y=Y-HSIN+DCOS
410 P4X=X-HCOS+DSIN:P4Y=Y-HSIN-DCOS
420 LINE (X0+P1X*Z,Y0-P1Y*Z)-(X0+P2X*Z,Y0-P2Y*Z),4
430 LINE (X0+P2X*Z,Y0-P2Y*Z)-(X0+P3X*Z,Y0-P3Y*Z),4
440 LINE (X0+P3X*Z,Y0-P3Y*Z)-(X0+P4X*Z,Y0-P4Y*Z),4
450 LINE (X0+P4X*Z,Y0-P4Y*Z)-(X0+P1X*Z,Y0-P1Y*Z),4
460 C1X=CT*COS(T)+CD*SIN(T):C1Y=CT*SIN(T)-CD*COS(T)     '---------シリンダ
470 C2X=CT*COS(T)-CD*SIN(T):C2Y=CT*SIN(T)+CD*COS(T)
480 C3X=CT*COS(T)-CD*SIN(T)-CL*COS(T):C3Y=CT*SIN(T)+CD*COS(T)-CL*SIN(T)
490 C4X=CT*COS(T)+CD*SIN(T)-CL*COS(T):C4Y=CT*SIN(T)-CD*COS(T)-CL*SIN(T)
500 LINE (X0+C4X*Z,Y0-C4Y*Z)-(X0+C1X*Z,Y0-C1Y*Z),7
510 LINE (X0+C1X*Z,Y0-C1Y*Z)-(X0+C2X*Z,Y0-C2Y*Z),7
520 LINE (X0+C2X*Z,Y0-C2Y*Z)-(X0+C3X*Z,Y0-C3Y*Z),7
530 NEXT T
540 NEXT S
550 GOTO 220